共享基本脚本（带注释）不定时更新

啊对对对

楼上说的对。。让我多买几个版本，拆脚本出来发帖。哈哈

啊对对对

今天分享一个限时进入地图的小脚本。

;比如有一个地图，我想让玩家晚上7:10-7:50的时候进入。在NPC传送脚本这样写就行。
[@main]
你好，亲爱的玩家，我这里可以传送到<最终地图/AUTOCOLOR=254,251,168,191,250,70,245,249,253>。
;这个<>里面是让最终地图这四个字  在254 251 168等颜色不停的变换。如果后面跟的是/FCOLOR=254  那就是让【最终地图】几个字固定为254这个颜色

<传送到终极地图/@传>            <我不去/@exit>
;这个不懂的看前面哦。
[@传]
#IF
HOUR 19 19
MIN 10 50
;24小时制   19时   10分-50分
CHECK [1] 1
;这个是检测标签的，比如有人买了会员的时候  你SET [1] 1 让他的标签1为1  。[1] 这个1就是1号标签的意思， 后面的1就是开启的意思 0的话就是关闭状态。CHECK [1] 0 就是检测1标签是不是关闭状态。
#ACT
mapmove ZJDT 50 50
;上面的条件都满足之后。传送到ZJDT 坐标 50 50这个地方。
give 回城卷 1
;然后给他一个回城卷，怕他没法回家。

1935619447

好东西让刚好让新人学习下

x6888144

他我哦哦哦哦哦

yt10123

感谢大佬的无私分享。

风趣

这个真的太好了，希望楼主继续加油。

x6888144

他咯哦哦哦哦哦

啊对对对

今天分享一个登录脚本，如果你发现服务器有人开挂或者干了别的坏事，不想让他登录  可以在QM文本文档添加以下：


#OR
;这个#OR和#IF用法一样。只是#IF下面的检测条件，必须要同时满足，才能进行下面的#ACT。但是#OR，只需要满足下列检测条件任何一个，就可以进行#ACT。之前做多品类兑换脚本的时候，先#IF 检测有没有某两样东西 如果没有 还需要GOTO到另一个。现在直接用#OR就可以简化脚本
EQUAL <$USERNAME> 你这西瓜保熟不
;EQUAL 就是变量等于的意思。 <$USERNAME> 这个是固定变量，名字的意思。 你这西瓜保熟不  就是说 如果登录的USERNAME = 你这西瓜保熟不  
EQUAL <$USERID> aa0125
EQUAL <$USERID> a7856800
;这个和USERNAME区别就是。 使用的是登录ID。就是你的账号
#ACT
MESSAGEBOX 开个几把挂！
;这个是消息盒子。 上面三个条件满足任何一项的人上线，就会提示他。

SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
SENDMSG 0 <$USERNAME>开挂已被封号，望周知！！！
;SENDMSG 0 后面的0可以换 0 1 2 3 4 等等数字。 对应了不同的系统提示  0是全服提示  6是绿字提示 7是蓝底白字提示   自己可以多试试
KICK 1
;KICK  是踢他下线的命令，  KICK 后面如果是0或者是空的 就会让他断线，如果是1 就是让他小退。


这是从狗哥版本里扒的...有时间我就扒一点出来给大家分享。。

啊对对对

分享一个基础的，单次领取物品的方法。
之前用过SET [1] 1 这样贴标签的方法，但是玩家换一个账号，还是可以再领取一次，这样就会造成重复领取，刷东西。所以今天分享一个检测机器码领取物品的方法，一台电脑理论上只能领取一次，除非他用虚拟机等手段。

[@main]
#IF
#SAY
\ \ \
<领取/@领取>
;上面这几段就不做赘述了，如果需要请来https://www.haom2.net/thread-634-1-1.html 从第一节看起。
[@领取]
#IF
Checktextlist ..\QuestDiary\机器码.txt <$MACHINEID>
;这个是检测  机器码.txt这个文本文档的内容有没有该玩家的机器码。<$MACHINEID> 这个是机器码的固定变量。
首先在QuestDiary文件夹创建一个机器码.txt文本文档，这时候他是空的。
#Act
MessageBox 每人限领一次
;如果机器码在文本文档里，就不给东西，弹一个消息盒子。
#ELSEACT
;如果不满足上面的检测条件。在我们这里，就是指，该玩家的机器码不在文本里。
AddTextList ..\QuestDiary\机器码.txt <$MACHINEID>
;在机器码.txt 里面写下该玩家的机器码。这一步就是对应上面的检测条件。
GAMEGOLD + 500000
;元宝 + 500000，这里可以给你想给的任何东西，ADDSKILL 火球术 3 就是让他学会3级火球术。
GIVE 木剑 1 就是给一个木剑。
SENDMSG 0 253 251 恭喜你领取成功！！！！！！!
;全服提示。
BREAK

仅供小白参考，大神请无视~

啊对对对

分享一个泡点的脚本，从加地图开始。这个也是从别人那里扒的/huaix

1、打开MapInfo.txt，加入地图配置文件：
[XEPD|0139 险恶泡点] NORECONNECT(3) NOTALLOWUSEITEMS(行会召唤令) NORECALL NOGUILDRECALL NODEARRECALL NOMasterRECALL
[HYPD|B136 会员泡点①] SAFE NORECONNECT(3) NOTALLOWUSEITEMS(行会召唤令) NORECALL NOGUILDRECALL NODEARRECALL NOMasterRECALL
[HYPDD|B136 会员泡点②] SAFE NORECONNECT(3) NOTALLOWUSEITEMS(行会召唤令) NORECALL NOGUILDRECALL NODEARRECALL NOMasterRECALL
;这个是调用客户端原有地图素材，开放一个泡点用的地图。
;[XEPD|0139] 这个作为例子，XEPD是你创建的新地图的编号，GM可以@F XEPD 直接过去。@F的命令不一定一样 在M2自查。
;      |0139  这个是一个分隔符加上原有地图的编号。险恶泡点，就是玩家进地图之后看到的地图名字。
;NORECONNECT(3) 就是说，小退再上，就会到3这个地图编号，3就是盟重。 NOTALLOWUSEITEMS(行会召唤令)，禁止使用 行会召唤令，泡点地图能用这玩意还不炸了。
;NORECALL NOGUILDRECALL NODEARRECALL NOMasterRECALL  这几个就是禁止记忆套传送，行会传送，夫妻传送，师徒传送。
;会员泡点有个 SAFE   这说明当前地图是不能PK的。
2、打开QManage.txt，加入以下脚本：
[@OnTimer1]
;这个是个人计时器，下面的脚本会有对应的SETONTIMER 1
#IF
ISONMAP XEPD
;如果玩家在 XEPD 这个地图里
CHECKLEVELEX < 70
;等级小于70
#ACT
;执行
CHANGEEXP + 500
;执行 经验 + 500 一次，注意：这里只加一次。
BREAK
#ELSEACT
;如果玩家不在XEPD地图或者级别超过69
GOTO @休止计时器
;去到 @休止计时器这个脚本，进行下一步检测和执行。
[@休止计时器]
#IF
ISONMAP XEPD
;如果在 XEPD这个地图
#ACT
;执行
SetOffTimer 1
;关闭一号计时器。因为上面我们写了两个检测条件，一个是在XEPD地图 一个是70级以下，跳转过来之后肯定是两个条件有一个不满足。那么我们先检测他在不在这个地图，如果在执行的就是下面这个。
MAPMOVE 3 330 333
;传送到3号地图 330 333  就是盟重安全区
SendMsg 5 孩子你已经有70级啦，我得把你送回家咯
;系统给他提示，他已经70了。
BREAK
#ELSEACT
;如果他不在这个地图，可能他自己用了回城，或者被打死了。级别可能不到70.那么我们可以不给提示。
SetOffTimer 1
;关闭一号个人计时器
break


[@OnTimer2]
#IF
ISONMAP HYPD
CHECKLEVELEX < 70
#ACT
CHANGEEXP + 1000
BREAK
#ELSEACT
GOTO @休止计时器2
[@休止计时器2]
#IF
ISONMAP HYPD
#ACT
SetOffTimer 2
MAPMOVE 3 330 333
SendMsg 5 孩子你已经有70级啦，我得把你送回家咯
BREAK
#ELSEACT
SetOffTimer 2
break
;这个同上。区别就是经验是+1000

[@OnTimer4]
#IF
ISONMAP HYPDD
CheckGold 1999
;这里加了一个检测金币的，是一个收金币的泡点房。
CHECKLEVELEX < 70
#ACT
take 金币 2000
CHANGEEXP + 3000
BREAK
#ELSEACT
GOTO @休止计时器4
[@休止计时器4]
#IF
ISONMAP HYPDD
#ACT
SetOffTimer 4
MAPMOVE 3 330 333
SendMsg 5 孩子你身上钱不够或者已经有70级啦，我得把你送回家咯
BREAK
#ELSEACT
SetOffTimer 4
break
;基本同上，区别就是收金币泡点，和经验+3000



3、在Market_Def文件夹下，新建一个泡点-3.txt，加入以下脚本：
;泡点就是添加NPC的时候对应的文本文档的文字。一般NPC名字和文本文档是一样，当然也可以不一样..NPC的名字可以叫泡点房，文本文档可以叫别的。可以。但是没必要
;-3其实就是方便索引， 3是盟重的地图编号，正常NPC在哪里，后面就加-地图编号。
[@main]
#IF
#ACT
#SAY
<本服人物等级/SCOLOR=151><70级/SCOLOR=249><封顶，是稳定长期耐玩的版本  ./SCOLOR=151>\
<╔━━━━━━━━━━━━━━━━━━━━━━━━━━━╗/SCOLOR=250>\
<┃/SCOLOR=250><免费泡点/@免费泡点1>←<安全泡点/SCOLOR=250>，每秒< 500/SCOLOR=250>经验，50级以后靠手动升级  <┃/SCOLOR=250>\
<┃/SCOLOR=250><会员泡点/@会员泡点1>←<险恶泡点/SCOLOR=250>，每秒<1000/SCOLOR=250>经验，赞助会员才可以进入！<┃/SCOLOR=250>\
<┃/SCOLOR=250><贵宾泡点/@会员泡点2>←<安全泡点，每秒3000经验，收费2000金币/秒/SCOLOR=254>        <┃/SCOLOR=250>\
<╚━━━━━━━━━━━━━━━━━━━━━━━━━━━╝/SCOLOR=250>\
<本服升级经验绝对高，轻松升到本服/SCOLOR=151><70级封顶.值得推荐的一款游戏/SCOLOR=151>\
;NPC对话文本，不再赘述了，前面有详细讲解。

[@免费泡点1]
#IF
CheckLevelEx < 70
;检测等级
#ACT
MapMove XEPD
;玩家传送到 XEPD这个地图
give 回城卷 1
;给一个回城
SetOnTimer 1 1
;打开个人计时器1 1秒检测一次。 对应了上面QManage.txt [@ontimer1]
SENDMSG 7 已开启『免费泡点』险恶泡点功能！
SendMsg 0 玩家『%s』进入【险恶泡点】，免费享受每秒500经验！
#elseact
messagebox 等级超过70级！！！
break

[@会员泡点1]
#IF
checknamelist ..\QuestDiary\赞助大使封号\赞助大使名单.txt
;这里要检测一个文本文档，namelist 明显就是检测名字，如果用变量的话 就是checktextlist ..\QuestDiary\赞助大使封号\赞助大使名单.txt <$USERNAME>，这个也是检测名字的。
CheckLevelEx < 70
#ACT
MapMove HYPD
give 回城卷 1
SetOnTimer 2 1
;打开个人计时器2号 1秒执行一次。
SENDMSG 0 富豪【%s】去了会员包厢|每一秒1000经验增加
#elseact
messagebox 你不是会员.或者等级超过70级，！！！
break

[@会员泡点2]
#IF
CheckLevelEx < 70
#act
give 回城卷 1
mapmove HYPDD
SetOnTimer 4 1
;打开个人计时器4号 1秒执行一次。
SENDMSG 0 富豪【%s】去了老板包厢|每一秒3000经验增加
#elseact
messagebox 您等级己经超过70级！！！
break

这里串起来就能看出来,如果玩家70就会关闭计时器，就不会检测是否在泡点房和是否70级。  玩家如果不在泡点房，也会关闭计时器。
更多免费注释脚本，来https://www.haom2.net/thread-634-1-1.html查阅