共享基本脚本（带注释）不定时更新

啊对对对

1：点击NPC法师领取宝宝脚本


[@main]
;前面加了分号，意思就是这行只是注释，不算脚本。
这里可以让法师领取宝宝\
点击下方按钮进入领取页面\
;这句是NPC对话框的内容，可以随意编辑。符号\是换行的意思，可以不用回车直接\ 但是为了看的更舒服，我一般\后回车
<我要领取/@法师领宝宝>
;<>一定要加 里面的【我要领取】是按钮显示的文字，/@法师领宝宝  是点击按钮运行的脚本  汉字内容可以随意更改。  

[@法师领宝宝]
;这个[]里面填写上面按钮对应的@文字
<法师宝宝/FCOLOR=254> <Hot~/FCOLOR=249> <人在江湖飘啊，哪有不挨刀啊，选几个宝宝挡挡刀吧~/FCOLOR=31>\
;这行<>里面是文字/Fcolor  不是@  是让<>里面的文字变成指定颜色。
『<领取虎卫|69#15级以上法师免费领取/@虎卫>』
;<>左右可以加别的括号美化一下，这个算字符，只是好看。<>后面跟得是/@文字，说明是个按钮。领取虎卫后面是   |   这个代表鼠标移动到按钮上显示的提示，  69#是后面文字的颜色   不写默认白色。 15级以上法师免费领取  这就是鼠标放到按钮的悬浮提示，可以任意更改。


[@虎卫]
#IF
;如果，这个是固定格式
checkjob wizard
;检测职业  法师  如果是战士或者是道士 Warrior（战士） Taoist（道士）
CHECKSLAVECOUNT < 5
;检测当前携带宝宝数量 可以加> < =三个符号
CHECKLEVELex        >        14
;检测当前角色级别，可以用> < =三个符号    check什么什么 符号 参数    这三个之间，可以用空格，也可以用TAB的分隔符，作用一样。看个人喜好
#ACT
;执行的意思  就是执行下面的脚本命令
RECALLMOB 虎卫 5 43200        1
;给角色宝宝 宝宝名称 多少级 多少秒后叛变 数量
SendMsg 1 {信息ぐ|151:0:1}：法师「{%s|227:0:1}」在土城{《法师领宝宝》|223:0:1}免费领取了虎卫！
;公屏提示  sendmsg 后面有 0 1 2 3 4 5 6 具体效果自己尝试。 {信息ぐ|151:0:1} 这个大括号里面是文字，和文字颜色 文字底色    151  227 223 是文字颜色  这里的数字可以自己更改看看效果  ，文字和颜色控制中间要加  |   符号。
#ELSESAY
;如果检测条件不通过的话。我们这个脚本就是宝宝大于等于5个  或者级别不大于14.就在对话框显示下面的文字，文字可以随意更改！
你宝宝太多了，养不活

;这个就是NPC对话框显示的文字，可以随意更改。


纯手打,自己服写的小白脚本。大神请无视。。

442671

我建议标注颜色.

Atlantica

感谢分享，赞一个

3751402

感谢大佬的无私分享。

啊对对对

2：项链随机加幸运

[@main]
;上面是NPC对话框固定抬头
在我这里可帮你们升级幸运项链\
;NPC对话框文字，可随意更改
<升级幸运项链/@升级>    \
;按钮，具体的看楼上第一个，有具体介绍

[@升级]
;上面按钮跳转到这里继续执行
        \        \        \<升级幸运一/@幸运1>：<1000W+你身上的项链无幸运>\
<升级幸运二/@幸运2>：<3000W+你身上的项链幸运一>\
; 三个\符号就是换行，<升级幸运一/@幸运1>是按钮和按钮跳转。：<1000W+你身上的项链无幸运>\ 这个是文字  被<>包起来的文字，是红色的

[@幸运1]
;上面幸运1跳转过来
#IF
;检测固定的格式 #IF
CHECKITEMADDVALUE 3 1 = 1
;检测幸运 3号位置 就是项链 其余位置在说明书自查，    1就是幸运属性 =1 就是幸运是1. 每个位置对应的1是不同属性，比如3 1 就是项链的幸运属性，0 1 就是盔甲的魔御。这个说明书里面有具体的。
#ACT
;如果满足上面条件 就执行下面的脚本命令
MESSAGEBOX  你的项链已经幸运1了
;MESSAGEBOX 消息盒子，确定取消的那个小对话框。 文字就是框内文字内容。
BREAK
;结束 表示这个检测脚本结束

#IF
CHECKITEMADDVALUE 3 1 = 2
#ACT
MESSAGEBOX  你的项链已经幸运2了
BREAK
;同上，只不过是检测项链幸运2。对照幸运1的可以看出他们的区别就是3 1 = 1和 3 1 =2的区别。因为他们都是检测的3（项链） 1（项链的1号属性：幸运） = 若干  就是幸运几

#IF
random 10
;random 10 的意思是 随机在1-10选一个数值，如果这个值是10.那么就可以通过IF的检测，执行下面的ACT命令
CHECKGOLD 9999999
;检测金币 数量   如果是元宝就是gamegold   灵符什么的可以在说明书查到。这里有一点要注意，checkgold的时候 直接是空格 数字 就是大于数值的意思。如果是元宝 灵符 则是><=符号来控制。元宝脚本转金币脚本的时候这个很容易错。
CHECKITEMADDVALUE 3 1 = 0
;检测3（项链位置） 1（幸运属性）= 0
#ACT
;执行下面脚本命令
TAKE        金币        10000000
;拿走 金币 10000000  上面检测他有9999999以上 ，这个是小细节。
UPGRADEITEMEX 3 1 0 1 0
;依次为 提升属性 3（项链）1（幸运属性）0（成功几率，数字越大，成功率越小）1（升级成功加几点）0（升级是否破碎 0不破 1破碎）
SENDMSG 0 恭喜玩家【%s】把项链升级到幸运1........
SENDMSG 0 恭喜玩家【%s】把项链升级到幸运1........
;公屏提示
BREAK
#ELSEACT
;如果上面检测不通过则执行
TAKE        金币        10000000
;拿走金币 1000000
MESSAGEBOX   升级失败
;消息盒子  盒子提示内容
BREAK

[@幸运2]
#IF
CHECKITEMADDVALUE 3 1 = 2
#ACT
MESSAGEBOX  你的项链已经幸运2了
BREAK

#IF
CHECKITEMADDVALUE 3 1 = 0
#ACT
MESSAGEBOX  你的项链还没加幸运
BREAK
;上面两个检测条件，可以对照幸运1脚本下面的。会发现，幸运1是检测运1 运2然后怎么样  这里是检测运0 运2.因为运1我们就要执行下面的脚本
#IF
random 10
CHECKGOLD 29999999
CHECKITEMADDVALUE 3 1 = 1
#ACT
TAKE        金币        30000000
UPGRADEITEMEX 3 1 0 1 0
SENDMSG 0 恭喜玩家【%s】把项链升级到幸运2........
SENDMSG 0 恭喜玩家【%s】把项链升级到幸运2........
BREAK
#ELSEACT
TAKE        金币        30000000
MESSAGEBOX   升级失败
BREAK
;上面的和幸运1一样。

纯手打,这个细节就是升级运1的时候 要检测项链是否已经运1 运2 ，检测幸运2的时候 要检测是否运0运2   我当时写的时候就错了，造成运0的时候点升级幸运2也会扣钱升级，会被玩家骂。。。

小白可以参考，大神飘过~

wywywy339

谢谢大佬的分享！！！感谢

x6888144

很详细，谢谢大佬